MPF Extract	-More Clips -About NoteTab
This is a NoteTab Clip. Some version of NoteTab is required for use.

First, a little background...

Microsoft Clipart Gallery is a huge collection of images, sounds, and animations. It's meant to be an online extension of Microsoft Office. If you own Office (or a related product) and visit the online clipart collection, you select the media you'd like, then click download items. A little program called Clip Organizer (or Clip Gallery) then catches the download and extracts the images into your pictures folder and you have access to them directly, or through your MS Office Product.

Neato, nifty, and works like charm... unless you don't own Microsoft Office. In which case you end up downloading a file named ClipArt.mpf and have no idea what to do with it.

Well, the good news is that you CAN do something with it and it's not really all that difficult. An MPF file is nothing more than a text file... an XML file to be more specific. (an XML file is similar to an HTML file) You can open it in any text editor.

Here's a look inside a typical MPF file...

<?xml version="1.0"?>
<D:multistatus xmlns:D="DAV:" xmlns:C="urn:schemas-microsoft-com:office:clipgallery" xmlns:dt="urn:schemas-microsoft-com:datatypes">
	<D:response>
		<D:href>-Flat/{af105344-4dd8-4d45-aae4-77820a8d8466}</D:href>
		<D:propstat>
			<D:status>HTTP/1.1 200 OK</D:status>
			<D:prop>
				<C:subject>businesses,businessmen,carts of work,handcarts,loaded with work,males,men,metaphors,paperwork,People,persons,web animations,wheelbarrows</C:subject>
				<C:xsubject>businessman,handcart,male,man,person,web animation,wheelbarrow,j0286669,@Style=750</C:xsubject>
				<C:collections>/Downloaded Clips,/Downloaded Clips/Business,/Downloaded Clips/Web Elements,/Downloaded Clips/Abstract</C:collections>
				<C:type>Motion</C:type>
				<C:width>110</C:width>
				<C:height>99</C:height>
				<C:units><C:pixels/></C:units>
				<C:duration>0</C:duration>
				<D:getlastmodified>01/16/2006 00:00:00</D:getlastmodified>
				<D:getcontentlength>11309</D:getcontentlength>
				<C:resource>
					<C:filepath>j0286669.gif</C:filepath>
					<C:contents dt:dt="bin.base64">
R0lGODlhbgBjAPf/AP/////MzP+ZZsz//8zMzMzMmcyZmcyZZsxmZsxmM5 ...most of this line removed, it's usually VERY long... DMAAAAzMwAAAP//zP//mf//zP+Zmf+ZM/+ZAP9m//9mzP9mmf9mZv9mM/9mAP8z//8zzP8zmf8zZv8zM/8zAQEADs=
					</C:contents>
				</C:resource>
			</D:prop>
		</D:propstat>
etc, etc, blah, blah, blah...

If you look closely, you'll see it contains lots of information (metadata) about the media file (in this case a GIF animation). It contains the file name (j0286669.gif), its width (110) and height (99), keywords related to the image, and most importantly, the file data itself (the line that starts R0lGODlhbgBjA...)

That file data has been encoded from it's original binary form into a text format called Base64. In order for us to make use of the file data, that long text string has to be decoded back into it's orginal binary form. This can be done pretty easily with a command line Base64 encoder/decoder. (For the not so quick and dirty manual process, experienced users might wish to have a look at manually extracting data from MPF files. --hide this--

Manually extracting data from MPF files...

(Granted, there is more than one way to extract and decode data from an MPF file. This is one way.)

An MPF file can contain one media file, or several. If you selected multiple media files to download from the clipart gallery, then all those files will be contained in the single MPF file you downloaded (usually ClipArt.mpf)

Open ClipArt.mpf with a text editor.

Note the section <C:filepath>.This is the filename of a media file. There is other information in other sections, but for our purposes here, we don't need to concern ourselves with any of that.

A couple lines below the filename, you'll find the base64 encoded data section (a long line with a bunch of letters, numbers and symbols). If your text editor can handle REALLY long lines, this will all be on one line. If not, it won't. This is the data that will decode back into your media file.

If you downloaded multiple media files, then each media file will have its own section in the MPF file containing, among other things, a filename and a chunk of base64 encoded data.

To manually extract, that chunk of data needs to be copied and saved as a file. Doesn't matter what you call it. Save it as joe.txt for now. There doesn't need to be anything in the file but that raw data.

And you'll need a copy of base64.exe. Put everything in the same folder to keep things simple.

Open a command prompt in that folder. Remember the filename you found just above the base64 data? Let's suppose it was j12345.gif. You'll then use the following command line...

base64.exe -d joe.txt j12345.gif

If you did everything correctly, j12345.gif should appear in your folder and can then be used as you wish. You can delete joe.txt.

Lather, rinse and repeat the process for as many media files as are embedded in your MPF file.

Or... save yourself a little work and use the clip... For the easy-as-pie and slick-as-a-greased-pig NoteTab clip, continue reading...)

This NoteTab clip makes the whole process of extraction and decoding a breeze.

First, download, unzip and install the clip. In the zip file you will also find a copy of base64.exe. This is the command line encoder/decoder and MUST be placed in the same file as the clip.

Download mpfextract.zip

Second, make sure that when downloading media from Microsoft's site, you check "Import into Clip Organizer version 2002 or newer". This will give you an MPF file. (The other option, "Import into Clip Gallery version 5.0 or older" will give you a binary CIL file which we cannot use.)

Third, run the clip through NoteTab and when prompted, choose your MPF file and a folder to place the decoded media files. Couldn't be simpler.

For those with some experience using NoteTab clips, you can simply grab the code below and do with it what you wish. All the code is contained in that one clip. You can place it within another clip library or in its own library. Name it whatever you wish. Just be sure to grab base64.exe which you will also need. Place it wherever you place the clip.

show clip

^!Continue MPF Extract v1.0^%NL%a NoteTab clip by Joe Barta - HTMLisEasy.com^%NL%https://www.htmliseasy.com/notetab/mpfextract.html^%NL%^%NL%Effortlessly extract media from Microsoft Office Clipart Gallery files. (ClipArt.mpf)^%NL%^%NL%Full details and instructions at the web site above. Requires base64.exe to function. (also available at the web site above)^%NL%^%NL%Click OK to proceed.

; =============================================================================
;  MPF Extract v1.0
;  a NoteTab clip by Joe Barta - HTMLisEasy.com
;  https://www.htmliseasy.com/notetab/mpfextract.html
;
;  Effortlessly extract media from Microsoft Office Clipart Gallery files (ClipArt.mpf)
;  Full details and instructions at the web site above.
;  Requires base64.exe to function. Also available at the web site above.
; =============================================================================

;get files
^!Set %infile%=^?[(T=O;F="MPF Files (*.mpf)|*.mpf")Open MPF file:=]
^!Set %outfolder%=^?[(T=D)Save decoded files in folder:]

:CHECK_MPF_INPUT
^!If ^$StrSize(^%infile%)$ > 3 SKIP_3
^!Continue Please choose an MPF file. Press Ok to try again or Cancel to abort.
^!Set %infile%=^?{(T=O;F="MPF Files (*.mpf)|*.mpf")Open MPF file:=}
^!Goto CHECK_MPF_INPUT

:CHECK_OUTPUT_FOLDER
^!If ^$StrSize(^%outfolder%)$ > 3 SKIP_3
^!Continue Please choose an output folder. Press Ok to try again or Cancel to abort.
^!Set %outfolder%=^?{(T=D)Save decoded files in folder:}
^!Goto CHECK_OUTPUT_FOLDER


;get this clip file path
^!Set %library_name_length%=^$Calc(^$StrSize(^$GetLibraryName$)$+4)$
^!Set %library_filename_length%=^$StrSize(^$GetLibraryFileName$)$
^!Set %library_filepath_length%=^$Calc(^%library_filename_length%-^%library_name_length%)$
^!Set %library_filepath%=^$StrCopyLeft(^$GetLibraryFileName$;^%library_filepath_length%)$


^!IfFileExist "^%library_filepath%base64.exe" SKIP_2
^!Prompt Cannot find base64.exe. Aborting clip.^%NL%^%NL%Base64.exe is used to decode your files after they've been extracted from the MPF file. It should be placed in your NoteTab Libraries folder along with this clip.
^!Goto EXIT


^!Set %process_fileline%=1


^!SetScreenUpdate Off

^!Open ^%infile%
^!SetWordWrap OFF
^!Set %process_fileline%=1
^!Set %files_decoded%=0


:FIND_AND_DECODE_FILES
^!SetCursor ^%process_fileline%:1

;get outputfilename
^!Find <C:filepath> TS
^!Set %row%=^$GetRow$
^!If ^%row% = ^%process_fileline% OUT_OF_FILES_TO_DECODE
^!SetCursor ^%row%:1
^!Find > TS
^!Set %col%=^$Calc(^$GetCol$+1)$
^!SetCursor ^%row%:^%col%
^!Find < TS
^!Set %col2%=^$Calc(^$GetCol$)$
^!SetCursor ^%row%:^%col%
^!SelectTo ^%row%:^%col2%
^!Set %outputfilename%=^$GetSelection$
^!StatusShow Extracting and decoding file ^$Calc(^%files_decoded%+1)$

;get data beginrow
^!Set %data_begin_row%=^$Calc(^$GetRow$+2)$

;get data endrow
^!Find </C:contents> TS
^!Set %data_end_row%=^$Calc(^$GetRow$-1)$
^!Set %process_fileline%=^%data_end_row%

;get data endcol
^!SetCursor ^%data_end_row%:1
^!Jump LINE_END
^!Set %data_end_col%=^$GetCol$

;get data
^!SetCursor ^%data_begin_row%:1
^!SelectTo ^%data_end_row%:^%data_end_col%
^!Set %b64data%=^$GetSelection$

;save data file
^!Toolbar New Document
^!SetWordWrap OFF
^!InsertText ^%b64data%
^!Save AS ^%outfolder%temp.b64
^!Toolbar Close Document

;decode data file
^!CmdShow Minimize
^!ShellWait "^%library_filepath%base64.exe" -d -n "^%outfolder%temp.b64" "^%outfolder%^%outputfilename%"
^!Set %files_decoded%=^$Calc(^%files_decoded%+1)$


^!Goto FIND_AND_DECODE_FILES


:OUT_OF_FILES_TO_DECODE
^!DestroyDoc ^%outfolder%temp.b64
^!Toolbar Close Document

^!StatusClose
^!SetScreenUpdate On

^!Prompt All done!^%NL%^%NL%^%files_decoded% files extracted and decoded.
^!CmdShow Normal
^!Shell ^%outfolder%


:EXIT